buch_des_monats/src/buchdesmonats/core.clj

;;; Copyright (C) 2014-2019 Aaron Fischer <mail@aaron-fischer.net>
;;; 
;;; Permission is hereby granted, free of charge, to any person obtaining a copy of
;;; this software and associated documentation files (the "Software"), to deal in
;;; the Software without restriction, including without limitation the rights to
;;; use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of
;;; the Software, and to permit persons to whom the Software is furnished to do so,
;;; subject to the following conditions:
;;; 
;;; The above copyright notice and this permission notice shall be included in all
;;; copies or substantial portions of the Software.
;;; 
;;; THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
;;; IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS
;;; FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR
;;; COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
;;; IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
;;; CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

(ns buchdesmonats.core
  (:gen-class)
  (:require [net.cgrand.enlive-html :as html]
            [clj-http.client :as http-client]
            [clojure.string :as str]
            [clojure.java.io :as io]
            [clojure.tools.logging :as log]
            [me.raynes.fs :as fs]))

;; TODO: Make it compatible to other book cover sites
(defn imgurl->bytes [lovelybooks-url]
  (let [urls (-> (java.net.URL. lovelybooks-url)
                 html/html-resource
                 (html/select [:img.ResponsiveImage.BookCover])
                 first
                 (get-in [:attrs :srcset])
                 (str/split #" "))
        url-to-fetch (last (filter #(re-matches #"http.+\.jpg" %) urls))
        stream (http-client/get url-to-fetch {:as :byte-array})]
    (:body stream)))

(defn encode-url-part [part]
  (java.net.URLEncoder/encode part "UTF-8"))

(defn encode-url [url]
  (let [parts (map encode-url-part (re-find #"\/autor\/([^/]+)\/([^/]+)\/?" url))
        author (nth parts 1)
        book-title (nth parts 2)]
    (str "https://lovelybooks.de/autor/" author "/" book-title)))

(defn url->file [lovelybooks-url target-dir]
  (let [[_ author title] (re-find #".\/autor\/([^\/]+)\/(.+)-([0-9]+)-.\/$" lovelybooks-url)]
    (-> (str author "_" title ".jpg")
        str/lower-case
        (str/replace #"[^a-z0-9-_.]" "")
        (#(io/file target-dir %)))))

(defn scrape-book-urls [datasource-url]
  (->> (http-client/get datasource-url {:insecure? true})
       :body
       str/split-lines
       (map #(second (re-find #"^\* .*\[.+\]\((.+)\)" %)))
       (remove nil?)))

(defn scrape-book-cover [url target-dir]
  (try
    (let [target-file (url->file url target-dir)
          encoded-url (encode-url url)
          bytes (imgurl->bytes encoded-url)]
      (with-open [out (io/output-stream target-file)]
        (.write out bytes)))
    (catch Exception e
      ;; TODO: Better exception (examine e?)
      (log/info "Problems with " url ", skip it."))))

(defn find-missing-covers [books-url target-dir]
  (remove #(fs/exists? (url->file % target-dir))
          (scrape-book-urls books-url)))

(defn cover-item-model-for-type [type]
(html/defsnippet cover-item-model (str "buchdesmonats/" type ".html") [:div#covers :> :div]
  [link title]
  [:a] (html/set-attr :href link)
  [:img] (html/set-attr :src (url->file link (str type "-covers")) :title title)))

(defn template-for-type [type]
(html/deftemplate book-template (str "buchdesmonats/" type ".html")
  [cover-urls]
  [:#covers] (html/content
              (map #((cover-item-model-for-type type) % "zu Lovely Books")
                   cover-urls))))

(defn generate-html [type book-urls target-dir]
  (let [content (apply str ((template-for-type type) book-urls))]
    (with-open [out (io/writer (io/file target-dir (str type ".html")))]
      (.write out content))))

(defn -main [& args]
  (let [type (first args)
        datasource-url (str "https://git.okoyono.de/mezzomix/buch_des_monats/raw/master/" (clojure.string/upper-case type) ".mkd")
        target-dir (io/file "public" (str type "-covers"))]
    (fs/mkdirs target-dir)
    (generate-html type (scrape-book-urls datasource-url) "public")
    (doall (pmap #(scrape-book-cover % target-dir)
                 (find-missing-covers datasource-url target-dir)))
    (System/exit 0)))