weatherstation/firmware/firmware.ino

#include <WiFiClient.h>
#include <ESP8266mDNS.h>
#include <ESP8266HTTPUpdateServer.h>
#include <ESP8266WiFi.h>
#include <DNSServer.h>
#include <ESP8266WebServer.h>
#include <WiFiManager.h>       // WiFiManager
#include <ESP8266Influxdb.h>   // https://github.com/hwwong/ESP8266Influxdb auchecken und den ordner in das arduino\library verzeichnis kopieren
#include <Adafruit_Sensor.h>   // PAckage Adafruit Unified Sensor
#include <Adafruit_APDS9960.h> // Adafruit APDS9960 - https://www.makerfabs.com/index.php?route=product/product&product_id=281
#include <Adafruit_BME280.h>   // BME280 - https://www.roboter-bausatz.de/1704/bmp280-barometer-luftdrucksensor?gclid=EAIaIQobChMIlpumj8Hp2wIVFWYbCh01PgmFEAQYAyABEgIwBvD_BwE

#include "config.h"

//*************************************************************************//

/**
 * Whishlist:
 * - Webserver for /metrics endpoint (Prometheus)
 * - Show current sensor values over simple webpage
 * - Push sensor values to various 3rd party services (https://openweathermap.org/)
 * - MQTT?
 * 
 * - Buffer sensor values if there is no WIFI connection
 * - Configure weather station over http webinterface
 * - OTA firmware update
 * 
 * TODO:
 * - https://sminghub.github.io/Sming/about/ 
 * - https://github.com/marvinroger/homie-esp8266
 */

//*************************************************************************//

float currentSensorData[6] = {0.0, 0.0, 0.0, 0.0, 0.0, 0.0};

uint16_t update_sensor_cnt    = 0;
uint16_t update_webserver_cnt = 0;
uint16_t energySavingIterations = 0;

WiFiManager wifiManager;
Influxdb influxdb(INFLUXDB_HOST, INFLUXDB_PORT);
Adafruit_APDS9960 apds;
Adafruit_BME280 bme;

String localIP = "127.0.0.1";

//*************************************************************************//

void setup() {
  //WiFi.disconnect(); // erase the wifi credentials

#ifdef DEBUG
  Serial.begin(115200);
#endif

  // Pin settings
  pinMode(STATUS_LED_PIN, OUTPUT);
  pinMode(ANEMOMETER_PIN, INPUT_PULLUP);
  pinMode(A0, INPUT);

  digitalWrite(STATUS_LED_PIN, LOW);

  criticalBatCheck();

  // Establish WiFi connection
  String wifiName = "oko-weather-" + String(ESP.getChipId());

  wifiManager.setMinimumSignalQuality(15);
  wifiManager.setConnectTimeout(60); // the time in seconds to wait for the known wifi connection
  wifiManager.setTimeout(60); // the time in seconds to wait for the user to configure the device

  if (!wifiManager.autoConnect(wifiName.c_str(), "DEADBEEF")) {
#ifdef DEBUG
    Serial.println("WiFi connection failed, we reboot ...");
#endif

    ESP.deepSleep(POWERSAVING_SLEEP_S * 1000000, WAKE_RF_DEFAULT);
    delay(100);
  }

#ifdef DEBUG
  Serial.println("Connected!");
#endif

  // Open the InfluxDB session
  influxdb.opendb(INFLUXDB_DB, INFLUXDB_USER, INFLUXDB_PASS);

  // Initialize and configure the sensors
  apds.begin();
  apds.enableColor(true);

  bool status = bme.begin(0x76);
  if (!status) {
#ifdef DEBUG
    Serial.println("Could not find a valid BME280 sensor, check wiring!");
#endif
    while (1);
  }

#ifdef WEBUPDATER_FEATURE
#ifndef POWERSAVING
  setupWebUpdater();
  localIP = WiFi.localIP().toString();
#endif
#endif

  delay(100);

#ifdef POWERSAVING
  _loop();

  digitalWrite(STATUS_LED_PIN, LOW);

  criticalBatCheck();

  WiFi.mode(WIFI_OFF);
  WiFi.forceSleepBegin();

  // the ESP.deepSleep requires microseconds as input, after the sleep the system will run into the setup routine
  ESP.deepSleep(POWERSAVING_SLEEP_S * 1000000, WAKE_RF_DEFAULT);
  delay(100);

#endif
}

//*************************************************************************//

void criticalBatCheck() {
  float volt = getBatteryVoltage();
  if (volt <= BAT_EMERGENCY_DEEPSLEEP_VOLTAGE) {
#ifdef DEBUG
    Serial.println("Bat Voltage: " + String(volt) + " V");
    Serial.println("Low battery, going into deep sleep.");
#endif
    ESP.deepSleep(EMERGENCY_SLEEP_S * 1000000); // battery low, shutting down
    delay(100);
  }
}

int energySavingMode() {
  // Give the solar panel some time to load the cell to prevent
  // flapping.
  if (energySavingIterations > 0) {
    energySavingIterations--;
    return 1;
  }

  // Is the battery low?
  if (currentSensorData[SENSOR_BAT_VOLTAGE] <= BAT_LOW_VOLTAGE) {
    // Entering energy saving
    energySavingIterations = ENERGY_SAVING_ITERATIONS;

    return 1;
  }
    
  return 0;
}

void loop() {
  criticalBatCheck();

#ifdef POWERSAVING
  delay(50);
  return;
#endif

#ifdef WEBUPDATER_FEATURE
  if (UPDATE_WEBSERVER_INTVERVAL_S * 1000 / DELAY_LOOP_MS <= update_webserver_cnt) {
    update_webserver_cnt = 0;
    doWebUpdater();
  }
#endif

  _loop();

  delay(DELAY_LOOP_MS);


  update_sensor_cnt++;

#ifdef WEBUPDATER_FEATURE
  update_webserver_cnt++;
#endif
}

void _loop() {

#ifndef POWERSAVING
  if (UPDATE_SENSOR_INTERVAL_S * 1000 / DELAY_LOOP_MS <= update_sensor_cnt) {
    update_sensor_cnt = 0;
#endif

    currentSensorData[SENSOR_TEMPERATURE] = fetchTemperature();
    currentSensorData[SENSOR_HUMIDITY]    = fetchHumidity();
    currentSensorData[SENSOR_LIGHT]       = fetchLight();
    currentSensorData[SENSOR_PRESSURE]    = fetchPressure();
    currentSensorData[SENSOR_BAT_VOLTAGE] = getBatteryVoltage();
    // Disable expensive tasks
    if (energySavingMode() == 0) {
      currentSensorData[SENSOR_WINDSPEED] = fetchWindspeed();
    } else {
      currentSensorData[SENSOR_WINDSPEED] = -1;
    }

#ifdef DEBUG
    Serial.println("");
    //Serial.println("Current readings:");
    Serial.println("Temperature: " + String(currentSensorData[SENSOR_TEMPERATURE]) + " °C");
    Serial.println("Humidity: " + String(currentSensorData[SENSOR_HUMIDITY]) + " %");
    Serial.println("Light: " + String(currentSensorData[SENSOR_LIGHT]) + " Lumen");
    Serial.println("Windspeed: " + String(currentSensorData[SENSOR_WINDSPEED]) + " km/h");
    Serial.println("Pressure: " + String(currentSensorData[SENSOR_PRESSURE]) + " hPa");
    Serial.println("Bat Voltage: " + String(currentSensorData[SENSOR_BAT_VOLTAGE]) + " V");
#endif

    delay(100);

    pushToInfluxDB(DEVICE_NAME, currentSensorData);
    
#ifdef WEBUPDATER_FEATURE
#ifndef POWERSAVING
    setSensorData(DEVICE_NAME, localIP, currentSensorData);
  }
#endif
#endif

}

//*************************************************************************//